Nick: heijligen
E-mail: none
Board: nix
Contents: 
{
  buildGoModule,
  fetchFromGitHub,
  pkg-config,
  libxcrypt,
  vips,

  stdenvNoCC,
  nodejs,
  pnpm,
  makeWrapper,
}:

let
  version = "2.2.0";
  
  src = fetchFromGitHub {
    owner = "opencloud-eu";
    repo = "opencloud";
    rev = "v${version}";
    hash = "sha256-yOsaT5bZbQAI1aMNROtoszDy42TqgurMrWfeRD3ST+o=";
  };

  web = stdenvNoCC.mkDerivation(finalAttrs: {
    pname = "opencloud-web1";
    version = "2.3.0";

    src = fetchFromGitHub {
      owner = "opencloud-eu";
      repo = "web";
      rev = "v${finalAttrs.version}";
      hash = "sha256-F59OOnnivrpsC5d6JuKB1Y+ApkASBBonV9nF7JkJWfw=";
    };

    nativeBuildInputs = [
      nodejs
      pnpm.configHook
    ];

    pnpmDeps = pnpm.fetchDeps {
      inherit (finalAttrs) pname version src;
      hash = "sha256-dsfiKf6AH0LWQYK79uewuAuPgxmFBWX6Vxbw/YV+Nk8=";
    };

    buildPhase = ''
      runHook preBuild
      pnpm build
      runHook postBuild
    '';

    installPhase = ''
      runHook preInstall
      mkdir $out
      cp -r dist/* $out
      runHook postInstall
    '';
  });

  idp-web = stdenvNoCC.mkDerivation(finalAttrs: {
    pname = "opencloud-idp-web";
    inherit version src;

    nativeBuildInputs = [
      nodejs
      pnpm.configHook
    ];

    pnpmRoot = "services/idp";

    pnpmDeps = pnpm.fetchDeps {
      inherit (finalAttrs) pname version src;
      sourceRoot = "${finalAttrs.src.name}/${finalAttrs.pnpmRoot}";
      hash = "sha256-q+Bvl8NnXrLW8rGXR5iddtp4S9xeduBniS0jd9WeSZw=";
    };

    buildPhase = ''
      runHook preBuild
      cd $pnpmRoot
      pnpm build
      runHook postBuild
    '';

    installPhase = ''
      runHook preInstall
      mkdir $out
      cp -r assets/* $out
      cp -v src/images/* $out/identifier/static/
      runHook postInstall
    '';
  });
  

in

buildGoModule (finalAttrs: {
  pname = "opencloud";
  inherit version src;

  vendorHash = null;

  excludedPackages = [ "tests/*" ];

  #ldflags = [
  # "-X github.com/opencloud-eu/opencloud/pkg/config/defaults.Bas..."
  # ];

  tags = [ "enable_vips" ];

  nativeBuildInputs = [
    pkg-config
    makeWrapper
  ];

  buildInputs = [
    libxcrypt
    vips
  ];

  doCheck = false;

  postInstall = ''
    wrapProgram "$out/bin/opencloud" \
      --set IDP_ASSET_PATH ${idp-web} \
      --set WEB_ASSET_CORE_PATH ${web}
  '';

  passthru = { inherit web idp-web; };
})